supercritical_initialization.F90

Go to the documentation of this file.

module supercritical_initialization

! This file is part of MOM6. See LICENSE.md for the license.

use mom_dyn_horgrid,    only : dyn_horgrid_type
use mom_error_handler,  only : mom_mesg, mom_error, fatal, is_root_pe
use mom_file_parser,    only : get_param, log_version, param_file_type
use mom_grid,           only : ocean_grid_type
use mom_open_boundary,  only : ocean_obc_type, obc_none, obc_simple, obc_segment_type
use mom_verticalgrid,   only : verticalgrid_type
use mom_time_manager,   only : time_type, set_time, time_type_to_real

implicit none ; private

#include <MOM_memory.h>

public supercritical_set_obc_data
public supercritical_initialize_topography

! This include declares and sets the variable "version".
#include "version_variable.h"

contains

!> This subroutine sets the properties of flow at open boundary conditions.
subroutine supercritical_set_obc_data(OBC, G, param_file)
  type(ocean_obc_type),   pointer    :: OBC  !< This open boundary condition type specifies
                                             !! whether, where, and what open boundary
                                             !! conditions are used.
  type(ocean_grid_type),  intent(in) :: G    !< The ocean's grid structure.
  type(param_file_type),  intent(in) :: param_file !< Parameter file structure
  ! Local variables
  character(len=40)  :: mdl = "supercritical_set_OBC_data" ! This subroutine's name.
  real :: zonal_flow
  integer :: i, j, k, l
  integer :: isd, ied, jsd, jed, IsdB, IedB, JsdB, JedB
  type(obc_segment_type), pointer :: segment ! pointer to segment type list

  if (.not.associated(obc)) call mom_error(fatal, 'supercritical_initialization.F90: '// &
        'supercritical_set_OBC_data() was called but OBC type was not initialized!')

  call get_param(param_file, mdl, "SUPERCRITICAL_ZONAL_FLOW", zonal_flow, &
                 "Constant zonal flow imposed at upstream open boundary.", &
                 units="m/s", default=8.57)

  do l=1, obc%number_of_segments
    segment => obc%segment(l)
    if (.not. segment%on_pe) cycle
    if (segment%gradient) cycle
    if (segment%oblique .and. .not. segment%nudged .and. .not. segment%Flather) cycle

    if (segment%is_E_or_W) then
      jsd = segment%HI%jsd ; jed = segment%HI%jed
      isdb = segment%HI%IsdB ; iedb = segment%HI%IedB
      do k=1,g%ke
        do j=jsd,jed ; do i=isdb,iedb
          if (segment%specified .or. segment%nudged) then
            segment%normal_vel(i,j,k) = zonal_flow
          endif
          if (segment%specified) then
            segment%normal_trans(i,j,k) = zonal_flow * g%dyCu(i,j)
          endif
        enddo ; enddo
      enddo
      do j=jsd,jed ; do i=isdb,iedb
        segment%normal_vel_bt(i,j) = zonal_flow
      enddo ; enddo
    else
      isd = segment%HI%isd ; ied = segment%HI%ied
      jsdb = segment%HI%JsdB ; jedb = segment%HI%JedB
!     do k=1,G%ke
!       do J=JsdB,JedB ; do i=isd,ied
!         segment%normal_vel(i,J,k) = 0.0
!       enddo ; enddo
!     enddo
      do j=jsdb,jedb ; do i=isd,ied
        segment%normal_vel_bt(i,j) = 0.0
      enddo ; enddo
    endif
  enddo

end subroutine supercritical_set_obc_data

!> This subroutine sets up the supercritical topography and land mask.
!! We were not able to get the shock wave to behave this way and are
!! now using an external file.
subroutine supercritical_initialize_topography(D, G, param_file, max_depth)
  type(dyn_horgrid_type),           intent(in)  :: G !< The dynamic horizontal grid type
  real, dimension(SZI_(G),SZJ_(G)), intent(out) :: D !< Ocean bottom depth in m
  type(param_file_type),            intent(in)  :: param_file !< Parameter file structure
  real,                             intent(in)  :: max_depth  !< Maximum depth of model in m
  ! Local variables
  character(len=40)  :: mdl = "supercritical_initialize_topography" ! This subroutine's name.
  real :: min_depth ! The minimum and maximum depths in m.
  real :: PI ! 3.1415...
  real :: coast_offset, coast_angle
  integer :: i, j

  call mom_mesg("  supercritical_initialization.F90, supercritical_initialize_topography: setting topography", 5)

  call log_version(param_file, mdl, version, "")
  call get_param(param_file, mdl, "MINIMUM_DEPTH", min_depth, &
                 "The minimum depth of the ocean.", units="m", default=0.0)
  call get_param(param_file, mdl, "SUPERCRITICAL_COAST_OFFSET", coast_offset, &
                 "The distance along the southern boundary at which the coasts angles in.", &
                 units="km", default=10.0)
  call get_param(param_file, mdl, "SUPERCRITICAL_COAST_ANGLE", coast_angle, &
                 "The angle of the southern bondary beyond X=SUPERCRITICAL_COAST_OFFSET.", &
                 units="degrees", default=8.95)

  coast_angle = coast_angle * (atan(1.0)/45.) ! Convert to radians

  do j=g%jsc,g%jec ; do i=g%isc,g%iec
    d(i,j)=max_depth
    if ((g%geoLonT(i,j) > coast_offset).AND. &
        (atan2(g%geoLatT(i,j),g%geoLonT(i,j) - coast_offset) < coast_angle)) then
      d(i,j)=0.5*min_depth
    endif

    if (d(i,j) > max_depth) d(i,j) = max_depth
    if (d(i,j) < min_depth) d(i,j) = 0.5*min_depth
  enddo ; enddo

end subroutine supercritical_initialize_topography

!> \namespace supercritical_initialization
!!
!! The module configures the model for the "supercritical" experiment.
!! https://marine.rutgers.edu/po/index.php?model=test-problems&title=supercritical
end module supercritical_initialization