soliton_initialization.F90

Go to the documentation of this file.

!> Initial conditions for the Equatorial Rossby soliton test (Boyd).
module soliton_initialization

! This file is part of MOM6. See LICENSE.md for the license.

use mom_error_handler, only : mom_mesg, mom_error, fatal, is_root_pe
use mom_file_parser, only : get_param, log_version, param_file_type
use mom_get_input, only : directories
use mom_grid, only : ocean_grid_type
use mom_io, only : close_file, fieldtype, file_exists
use mom_io, only : open_file, read_data, read_axis_data, single_file
use mom_io, only : write_field, slasher, vardesc
use mom_variables, only : thermo_var_ptrs
use mom_verticalgrid, only : verticalgrid_type
use mom_eos, only : calculate_density, calculate_density_derivs, eos_type
use regrid_consts, only : coordinatemode, default_coordinate_mode
use regrid_consts, only : regridding_layer, regridding_zstar
use regrid_consts, only : regridding_rho, regridding_sigma

implicit none ; private

#include <MOM_memory.h>

! Private (module-wise) parameters
character(len=40) :: mdl = "soliton_initialization" !< This module's name.

public soliton_initialize_thickness
public soliton_initialize_velocity

contains

!> Initialization of thicknesses in Equatorial Rossby soliton test
subroutine soliton_initialize_thickness(h, G)
  type(ocean_grid_type),   intent(in) :: G                 !< Grid structure
  real, dimension(SZI_(G),SZJ_(G), SZK_(G)), intent(out) :: h !< Thickness

  integer :: i, j, k, is, ie, js, je, nz
  real    :: x, y, x0, y0
  real    :: val1, val2, val3, val4
  character(len=40) :: verticalCoordinate

  is = g%isc ; ie = g%iec ; js = g%jsc ; je = g%jec ; nz = g%ke

  call mom_mesg("soliton_initialization.F90, soliton_initialize_thickness: setting thickness")

  x0 = 2.0*g%len_lon/3.0
  y0 = 0.0
  val1 = 0.395
  val2 = 0.771*(val1*val1)

  do j = g%jsc,g%jec ; do i = g%isc,g%iec
    do k = 1, nz
      x = g%geoLonT(i,j)-x0
      y = g%geoLatT(i,j)-y0
      val3 = exp(-val1*x)
      val4 = val2*((2.0*val3/(1.0+(val3*val3)))**2)
      h(i,j,k) = 0.25*val4*(6.0*y*y+3.0)*                 &
                exp(-0.5*y*y)
    enddo
  end do ; end do

end subroutine soliton_initialize_thickness


!> Initialization of u and v in the equatorial Rossby soliton test
subroutine soliton_initialize_velocity(u, v, h, G)
  type(ocean_grid_type),                  intent(in)     :: G  !< Grid structure
  real, dimension(SZIB_(G),SZJ_(G),SZK_(G)), intent(out) :: u  !< i-component of velocity [m/s]
  real, dimension(SZI_(G),SZJB_(G),SZK_(G)), intent(out) :: v  !< j-component of velocity [m/s]
  real, dimension(SZI_(G),SZJ_(G), SZK_(G)), intent(in)  :: h  !< Thickness [H]

  real    :: x, y, x0, y0
  real    :: val1, val2, val3, val4
  integer :: i, j, k, is, ie, js, je, nz

  is = g%isc ; ie = g%iec ; js = g%jsc ; je = g%jec ; nz = g%ke

  x0 = 2.0*g%len_lon/3.0
  y0 = 0.0
  val1 = 0.395
  val2 = 0.771*(val1*val1)

  v(:,:,:) = 0.0
  u(:,:,:) = 0.0

  do j = g%jsc,g%jec ; do i = g%isc-1,g%iec+1
    do k = 1, nz
      x = 0.5*(g%geoLonT(i+1,j)+g%geoLonT(i,j))-x0
      y = 0.5*(g%geoLatT(i+1,j)+g%geoLatT(i,j))-y0
      val3 = exp(-val1*x)
      val4 = val2*((2.0*val3/(1.0+(val3*val3)))**2)
      u(i,j,k) = 0.25*val4*(6.0*y*y-9.0)*         &
                      exp(-0.5*y*y)
    enddo
  enddo ; enddo
  do j = g%jsc-1,g%jec+1 ; do i = g%isc,g%iec
    do k = 1, nz
      x = 0.5*(g%geoLonT(i,j+1)+g%geoLonT(i,j))-x0
      y = 0.5*(g%geoLatT(i,j+1)+g%geoLatT(i,j))-y0
      val3 = exp(-val1*x)
      val4 = val2*((2.0*val3/(1.0+(val3*val3)))**2)
      v(i,j,k) = 2.0*val4*y*(-2.0*val1*tanh(val1*x))*        &
                     exp(-0.5*y*y)
    enddo
  enddo ; enddo

end subroutine soliton_initialize_velocity


!> \namespace soliton_initialization
!!
!! \section section_soliton Description of the equatorial Rossby soliton initial
!! conditions
!!

end module soliton_initialization