external_gwave_initialization.F90

Go to the documentation of this file.

module external_gwave_initialization
!***********************************************************************
!*                   GNU General Public License                        *
!* This file is a part of MOM.                                         *
!*                                                                     *
!* MOM is free software; you can redistribute it and/or modify it and  *
!* are expected to follow the terms of the GNU General Public License  *
!* as published by the Free Software Foundation; either version 2 of   *
!* the License, or (at your option) any later version.                 *
!*                                                                     *
!* MOM is distributed in the hope that it will be useful, but WITHOUT  *
!* ANY WARRANTY; without even the implied warranty of MERCHANTABILITY  *
!* or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public    *
!* License for more details.                                           *
!*                                                                     *
!* For the full text of the GNU General Public License,                *
!* write to: Free Software Foundation, Inc.,                           *
!*           675 Mass Ave, Cambridge, MA 02139, USA.                   *
!* or see:   http://www.gnu.org/licenses/gpl.html                      *
!***********************************************************************

use mom_error_handler, only : mom_mesg, mom_error, fatal, is_root_pe
use mom_file_parser, only : get_param, log_version, param_file_type
use mom_get_input, only : directories
use mom_grid, only : ocean_grid_type
use mom_tracer_registry, only : tracer_registry_type
use mom_variables, only : thermo_var_ptrs
implicit none ; private

#include <MOM_memory.h>

public external_gwave_initialize_thickness

contains

! -----------------------------------------------------------------------------
!> This subroutine initializes layer thicknesses for the external_gwave experiment.
subroutine external_gwave_initialize_thickness(h, G, param_file, just_read_params)
  type(ocean_grid_type), intent(in) :: G                      !< The ocean's grid structure.
  real, dimension(SZI_(G),SZJ_(G),SZK_(G)), &
                           intent(out) :: h           !< The thickness that is being initialized, in m.
  type(param_file_type),   intent(in)  :: param_file  !< A structure indicating the open file
                                                      !! to parse for model parameter values.
  logical,       optional, intent(in)  :: just_read_params !< If present and true, this call will
                                                      !! only read parameters without changing h.

  real :: e0(szk_(g))     ! The resting interface heights, in m, usually !
                          ! negative because it is positive upward.      !
  real :: e_pert(szk_(g)) ! Interface height perturbations, positive     !
                          ! upward, in m.                                !
  real :: eta1D(szk_(g)+1)! Interface height relative to the sea surface !
                          ! positive upward, in m.                       !
  real :: ssh_anomaly_height ! Vertical height of ssh anomaly
  real :: ssh_anomaly_width ! Lateral width of anomaly
  logical :: just_read    ! If true, just read parameters but set nothing.
  character(len=40)  :: mdl = "external_gwave_initialize_thickness" ! This subroutine's name.
! This include declares and sets the variable "version".
#include "version_variable.h"
  integer :: i, j, k, is, ie, js, je, nz
  real :: PI, Xnondim

  is = g%isc ; ie = g%iec ; js = g%jsc ; je = g%jec ; nz = g%ke

  just_read = .false. ; if (present(just_read_params)) just_read = just_read_params

  if (.not.just_read) &
    call mom_mesg("  external_gwave_initialization.F90, external_gwave_initialize_thickness: setting thickness", 5)

  if (.not.just_read) call log_version(param_file, mdl, version, "")
  call get_param(param_file, mdl, "SSH_ANOMALY_HEIGHT", ssh_anomaly_height, &
                 "The vertical displacement of the SSH anomaly. ", units="m", &
                 fail_if_missing=.not.just_read, do_not_log=just_read)
  call get_param(param_file, mdl, "SSH_ANOMALY_WIDTH", ssh_anomaly_width, &
                 "The lateral width of the SSH anomaly. ", units="coordinate", &
                 fail_if_missing=.not.just_read, do_not_log=just_read)

  if (just_read) return ! All run-time parameters have been read, so return.

  pi = 4.0*atan(1.0)
  do j=g%jsc,g%jec ; do i=g%isc,g%iec
    xnondim = (g%geoLonT(i,j)-g%west_lon-0.5*g%len_lon) / ssh_anomaly_width
    xnondim = min(1., abs(xnondim))
    eta1d(1) = ssh_anomaly_height * 0.5 * ( 1. + cos(pi*xnondim) ) ! Cosine bell
    do k=2,nz
      eta1d(k) = -g%max_depth & ! Stretch interior interfaces with SSH
              + (eta1d(1)+g%max_depth) * ( real(nz+1-k)/real(nz) ) ! Stratification
    enddo
    eta1d(nz+1) = -g%max_depth ! Force bottom interface to bottom
    do k=1,nz
      h(i,j,k) = eta1d(k) - eta1d(k+1)
    enddo
  enddo ; enddo

end subroutine external_gwave_initialize_thickness
! -----------------------------------------------------------------------------

!> \namespace external_gwave_initialization
!!
!! The module configures the model for the "external_gwave" experiment.
!! external_gwave = External Gravity Wave
end module external_gwave_initialization