MOM_PressureForce.F90

Go to the documentation of this file.

!> A thin wrapper for Boussinesq/non-Boussinesq forms of the pressure force calculation.
module mom_pressureforce

! This file is part of MOM6. See LICENSE.md for the license.

use mom_diag_mediator, only : diag_ctrl, time_type
use mom_error_handler, only : mom_error, mom_mesg, fatal, warning, is_root_pe
use mom_file_parser, only : get_param, log_version, param_file_type
use mom_grid, only : ocean_grid_type
use mom_pressureforce_afv, only : pressureforce_afv_bouss, pressureforce_afv_nonbouss
use mom_pressureforce_afv, only : pressureforce_afv_init, pressureforce_afv_cs
use mom_pressureforce_mont, only : pressureforce_mont_bouss, pressureforce_mont_nonbouss
use mom_pressureforce_mont, only : pressureforce_mont_init, pressureforce_mont_cs
use mom_tidal_forcing, only : calc_tidal_forcing, tidal_forcing_cs
use mom_variables, only : thermo_var_ptrs
use mom_verticalgrid, only : verticalgrid_type
use mom_ale, only: ale_cs
implicit none ; private

#include <MOM_memory.h>

public pressureforce, pressureforce_init, pressureforce_end

! Pressure force control structure
type, public :: pressureforce_cs ; private
  logical :: analytic_fv_pgf !< If true, use the analytic finite volume form
                             !! (Adcroft et al., Ocean Mod. 2008) of the PGF.
  !> Control structure for the analytically integrated finite volume pressure force
  type(pressureforce_afv_cs), pointer :: pressureforce_afv_csp => null()
  !> Control structure for the Montgomery potential form of pressure force
  type(pressureforce_mont_cs), pointer :: pressureforce_mont_csp => null()
end type pressureforce_cs

contains

!> A thin layer between the model and the Boussinesq and non-Boussinesq pressure force routines.
subroutine pressureforce(h, tv, PFu, PFv, G, GV, CS, ALE_CSp, p_atm, pbce, eta)
  type(ocean_grid_type),                     intent(in)  :: G    !< The ocean's grid structure
  type(verticalgrid_type),                   intent(in)  :: GV   !< The ocean's vertical grid structure
  real, dimension(SZI_(G),SZJ_(G),SZK_(G)),  intent(in)  :: h    !< Layer thicknesses, in H (usually m or kg m-2)
  type(thermo_var_ptrs),                     intent(in)  :: tv   !< A structure pointing to various thermodynamic variables
  real, dimension(SZIB_(G),SZJ_(G),SZK_(G)), intent(out) :: PFu
  real, dimension(SZI_(G),SZJB_(G),SZK_(G)), intent(out) :: PFv
  type(pressureforce_cs),                    pointer     :: CS
  type(ale_cs),                              pointer     :: ALE_CSp
  real, dimension(:,:),                     optional, pointer     :: p_atm
  real, dimension(SZI_(G),SZJ_(G),SZK_(G)), optional, intent(out) :: pbce
  real, dimension(SZI_(G),SZJ_(G)),         optional, intent(out) :: eta


  if (cs%Analytic_FV_PGF) then
    if (gv%Boussinesq) then
      call pressureforce_afv_bouss(h, tv, pfu, pfv, g, gv, cs%PressureForce_AFV_CSp, &
                                   ale_csp, p_atm, pbce, eta)
    else
      call pressureforce_afv_nonbouss(h, tv, pfu, pfv, g, gv, cs%PressureForce_AFV_CSp, &
                                      p_atm, pbce, eta)
    endif
  else
    if (gv%Boussinesq) then
      call pressureforce_mont_bouss(h, tv, pfu, pfv, g, gv, cs%PressureForce_Mont_CSp, &
                                    p_atm, pbce, eta)
    else
      call pressureforce_mont_nonbouss(h, tv, pfu, pfv, g, gv, cs%PressureForce_Mont_CSp, &
                                       p_atm, pbce, eta)
    endif
  endif

end subroutine pressureforce

!> Initialize the pressure force control structure
subroutine pressureforce_init(Time, G, GV, param_file, diag, CS, tides_CSp)
  type(time_type), target, intent(in)    :: Time !< Current model time
  type(ocean_grid_type),   intent(in)    :: G    !< Ocean grid structure
  type(verticalgrid_type), intent(in)    :: GV   !< Vertical grid structure
  type(param_file_type),   intent(in)    :: param_file !< Parameter file handles
  type(diag_ctrl), target, intent(inout) :: diag !< Diagnostics control structure
  type(pressureforce_cs),  pointer       :: CS   !< Pressure force control structure
  type(tidal_forcing_cs), optional, pointer :: tides_CSp !< Tide control structure
#include "version_variable.h"
  character(len=40)  :: mdl = "MOM_PressureForce" ! This module's name.

  if (associated(cs)) then
    call mom_error(warning, "PressureForce_init called with an associated "// &
                            "control structure.")
    return
  else ; allocate(cs) ; endif

  ! Read all relevant parameters and write them to the model log.
  call log_version(param_file, mdl, version, "")
  call get_param(param_file, mdl, "ANALYTIC_FV_PGF", cs%Analytic_FV_PGF, &
                 "If true the pressure gradient forces are calculated \n"//&
                 "with a finite volume form that analytically integrates \n"//&
                 "the equations of state in pressure to avoid any \n"//&
                 "possibility of numerical thermobaric instability, as \n"//&
                 "described in Adcroft et al., O. Mod. (2008).", default=.true.)

  if (cs%Analytic_FV_PGF) then
    call pressureforce_afv_init(time, g, gv, param_file, diag, &
             cs%PressureForce_AFV_CSp, tides_csp)
  else
    call pressureforce_mont_init(time, g, gv, param_file, diag, &
             cs%PressureForce_Mont_CSp, tides_csp)
  endif

end subroutine pressureforce_init

!> Deallocate the pressure force control structure
subroutine pressureforce_end(CS)
  type(pressureforce_cs), pointer :: CS !< Pressure force control structure
  if (associated(cs)) deallocate(cs)
end subroutine pressureforce_end

!> \namespace mom_pressureforce
!!
!! This thin module provides a branch to two forms of the horizontal accelerations
!! due to pressure gradients. The two options currently available are a
!! Montgomery potential form (used in traditional isopycnal layer models), and the
!! analytic finite volume form.

end module mom_pressureforce