mom_checksums::hchksum Interface Reference

Detailed Description

Definition at line 56 of file MOM_checksums.F90.

Private functions
subroutine	chksum_h_2d (array, mesg, HI, haloshift, omit_corners, scale)
	chksum_h_2d performs checksums on a 2d array staggered at tracer points. More...
subroutine	chksum_h_3d (array, mesg, HI, haloshift, omit_corners, scale)
	chksum_h_3d performs checksums on a 3d array staggered at tracer points. More...

Functions and subroutines

chksum_h_2d()

subroutine mom_checksums::hchksum::chksum_h_2d ( real, dimension(hi%isd:,hi%jsd:), intent(in)  array, character(len=*), intent(in)  mesg, type(hor_index_type), intent(in)  HI, integer, intent(in), optional  haloshift, logical, intent(in), optional  omit_corners, real, intent(in), optional  scale  )

private

chksum_h_2d performs checksums on a 2d array staggered at tracer points.

Parameters

[in]	hi	A horizontal index type
[in]	array	The array to be checksummed
[in]	mesg	An identifying message
[in]	haloshift	The width of halos to check (default 0)
[in]	omit_corners	If true, avoid checking diagonal shifts
[in]	scale	A scaling factor for this array.

Definition at line 129 of file MOM_checksums.F90.

  type(hor_index_type),            intent(in) :: hi     !< A horizontal index type
  real, dimension(HI%isd:,HI%jsd:), intent(in) :: array !< The array to be checksummed
  character(len=*),                intent(in) :: mesg  !< An identifying message
  integer,               optional, intent(in) :: haloshift !< The width of halos to check (default 0)
  logical,               optional, intent(in) :: omit_corners !< If true, avoid checking diagonal shifts
  real,                  optional, intent(in) :: scale     !< A scaling factor for this array.

  real :: scaling
  integer :: bc0, bcsw, bcse, bcnw, bcne, hshift
  integer :: bcn, bcs, bce, bcw
  logical :: do_corners

  if (checkfornans) then
    if (is_nan(array(hi%isc:hi%iec,hi%jsc:hi%jec))) &
      call chksum_error(fatal, 'NaN detected: '//trim(mesg))
!   if (is_NaN(array)) &
!     call chksum_error(FATAL, 'NaN detected in halo: '//trim(mesg))
  endif
  scaling = 1.0 ; if (present(scale)) scaling = scale

  if (calculatestatistics) call substats(hi, array, mesg, scaling)

  if (.not.writechksums) return

  hshift = default_shift
  if (present(haloshift)) hshift = haloshift
  if (hshift<0) hshift = hi%ied-hi%iec

  if ( hi%isc-hshift<hi%isd .or. hi%iec+hshift>hi%ied .or. &
       hi%jsc-hshift<hi%jsd .or. hi%jec+hshift>hi%jed ) then
    write(0,*) 'chksum_h_2d: haloshift =',hshift
    write(0,*) 'chksum_h_2d: isd,isc,iec,ied=',hi%isd,hi%isc,hi%iec,hi%ied
    write(0,*) 'chksum_h_2d: jsd,jsc,jec,jed=',hi%jsd,hi%jsc,hi%jec,hi%jed
    call chksum_error(fatal,'Error in chksum_h_2d '//trim(mesg))
  endif

  bc0 = subchk(array, hi, 0, 0, scaling)

  if (hshift==0) then
    if (is_root_pe()) call chk_sum_msg("h-point:",bc0,mesg)
    return
  endif

  do_corners = .true. ; if (present(omit_corners)) do_corners = .not.omit_corners

  if (do_corners) then
    bcsw = subchk(array, hi, -hshift, -hshift, scaling)
    bcse = subchk(array, hi, hshift, -hshift, scaling)
    bcnw = subchk(array, hi, -hshift, hshift, scaling)
    bcne = subchk(array, hi, hshift, hshift, scaling)

    if (is_root_pe()) call chk_sum_msg("h-point:",bc0,bcsw,bcse,bcnw,bcne,mesg)
  else
    bcs = subchk(array, hi, 0, -hshift, scaling)
    bce = subchk(array, hi, hshift, 0, scaling)
    bcw = subchk(array, hi, -hshift, 0, scaling)
    bcn = subchk(array, hi, 0, hshift, scaling)

    if (is_root_pe()) call chk_sum_msg_nsew("h-point:",bc0,bcn,bcs,bce,bcw,mesg)
  endif

  contains

  integer function subchk(array, HI, di, dj, scale)
    type(hor_index_type), intent(in) :: hi
    real, dimension(HI%isd:,HI%jsd:), intent(in) :: array
    integer, intent(in) :: di, dj
    real, intent(in) :: scale
    integer :: bitcount, i, j, bc
    subchk = 0
    do j=hi%jsc+dj,hi%jec+dj; do i=hi%isc+di,hi%iec+di
      bc = bitcount(abs(scale*array(i,j)))
      subchk = subchk + bc
    enddo; enddo
    call sum_across_pes(subchk)
    subchk=mod(subchk,1000000000)
  end function subchk

  subroutine substats(HI, array, mesg, scale)
    type(hor_index_type), intent(in) :: hi
    real, dimension(HI%isd:,HI%jsd:), intent(in) :: array
    character(len=*), intent(in) :: mesg
    real, intent(in) :: scale
    integer :: i, j, n
    real :: amean, amin, amax

    amin = array(hi%isc,hi%jsc)
    amax = array(hi%isc,hi%jsc)
    n = 0
    do j=hi%jsc,hi%jec ; do i=hi%isc,hi%iec
      amin = min(amin, array(i,j))
      amax = max(amax, array(i,j))
      n = n + 1
    enddo ; enddo
    amean = reproducing_sum(array(hi%isc:hi%iec,hi%jsc:hi%jec))
    call sum_across_pes(n)
    call min_across_pes(amin)
    call max_across_pes(amax)
    amean = amean / real(n)
    if (is_root_pe()) call chk_sum_msg("h-point:",amean*scale,amin*scale,amax*scale,mesg)
  end subroutine substats

chksum_h_3d()

subroutine mom_checksums::hchksum::chksum_h_3d ( real, dimension(hi%isd:,hi%jsd:,:), intent(in)  array, character(len=*), intent(in)  mesg, type(hor_index_type), intent(in)  HI, integer, intent(in), optional  haloshift, logical, intent(in), optional  omit_corners, real, intent(in), optional  scale  )

private

chksum_h_3d performs checksums on a 3d array staggered at tracer points.

Parameters

[in]	hi	A horizontal index type
[in]	array	The array to be checksummed
[in]	mesg	An identifying message
[in]	haloshift	The width of halos to check (default 0)
[in]	omit_corners	If true, avoid checking diagonal shifts
[in]	scale	A scaling factor for this array.

Definition at line 706 of file MOM_checksums.F90.

  type(hor_index_type),             intent(in) :: hi !< A horizontal index type
  real, dimension(HI%isd:,HI%jsd:,:),  intent(in) :: array !< The array to be checksummed
  character(len=*),                  intent(in) :: mesg  !< An identifying message
  integer,                 optional, intent(in) :: haloshift !< The width of halos to check (default 0)
  logical,                 optional, intent(in) :: omit_corners !< If true, avoid checking diagonal shifts
  real,                    optional, intent(in) :: scale     !< A scaling factor for this array.

  real :: scaling
  integer :: bc0, bcsw, bcse, bcnw, bcne, hshift
  integer :: bcn, bcs, bce, bcw
  logical :: do_corners

  if (checkfornans) then
    if (is_nan(array(hi%isc:hi%iec,hi%jsc:hi%jec,:))) &
      call chksum_error(fatal, 'NaN detected: '//trim(mesg))
!   if (is_NaN(array)) &
!     call chksum_error(FATAL, 'NaN detected in halo: '//trim(mesg))
  endif
  scaling = 1.0 ; if (present(scale)) scaling = scale

  if (calculatestatistics) call substats(hi, array, mesg, scaling)

  if (.not.writechksums) return

  hshift = default_shift
  if (present(haloshift)) hshift = haloshift
  if (hshift<0) hshift = hi%ied-hi%iec

  if ( hi%isc-hshift<hi%isd .or. hi%iec+hshift>hi%ied .or. &
       hi%jsc-hshift<hi%jsd .or. hi%jec+hshift>hi%jed ) then
    write(0,*) 'chksum_h_3d: haloshift =',hshift
    write(0,*) 'chksum_h_3d: isd,isc,iec,ied=',hi%isd,hi%isc,hi%iec,hi%ied
    write(0,*) 'chksum_h_3d: jsd,jsc,jec,jed=',hi%jsd,hi%jsc,hi%jec,hi%jed
    call chksum_error(fatal,'Error in chksum_h_3d '//trim(mesg))
  endif

  bc0 = subchk(array, hi, 0, 0, scaling)

  if (hshift==0) then
    if (is_root_pe()) call chk_sum_msg("h-point:",bc0,mesg)
    return
  endif

  do_corners = .true. ; if (present(omit_corners)) do_corners = .not.omit_corners

  if (do_corners) then
    bcsw = subchk(array, hi, -hshift, -hshift, scaling)
    bcse = subchk(array, hi, hshift, -hshift, scaling)
    bcnw = subchk(array, hi, -hshift, hshift, scaling)
    bcne = subchk(array, hi, hshift, hshift, scaling)

    if (is_root_pe()) call chk_sum_msg("h-point:",bc0,bcsw,bcse,bcnw,bcne,mesg)
  else
    bcs = subchk(array, hi, 0, -hshift, scaling)
    bce = subchk(array, hi, hshift, 0, scaling)
    bcw = subchk(array, hi, -hshift, 0, scaling)
    bcn = subchk(array, hi, 0, hshift, scaling)

    if (is_root_pe()) call chk_sum_msg_nsew("h-point:",bc0,bcn,bcs,bce,bcw,mesg)
  endif

  contains

  integer function subchk(array, HI, di, dj, scale)
    type(hor_index_type), intent(in) :: hi
    real, dimension(HI%isd:,HI%jsd:,:), intent(in) :: array
    integer, intent(in) :: di, dj
    real, intent(in) :: scale
    integer :: bitcount, i, j, k, bc
    subchk = 0
    do k=lbound(array,3),ubound(array,3) ; do j=hi%jsc+dj,hi%jec+dj ; do i=hi%isc+di,hi%iec+di
      bc = bitcount(abs(scale*array(i,j,k)))
      subchk = subchk + bc
    enddo ; enddo ; enddo
    call sum_across_pes(subchk)
    subchk=mod(subchk,1000000000)
  end function subchk

  subroutine substats(HI, array, mesg, scale)
    type(hor_index_type), intent(in) :: hi
    real, dimension(HI%isd:,HI%jsd:,:), intent(in) :: array
    character(len=*), intent(in) :: mesg
    real, intent(in) :: scale
    integer :: i, j, k, n
    real :: amean, amin, amax

    amin = array(hi%isc,hi%jsc,1)
    amax = array(hi%isc,hi%jsc,1)
    n = 0
    do k=lbound(array,3),ubound(array,3) ; do j=hi%jsc,hi%jec ; do i=hi%isc,hi%iec
      amin = min(amin, array(i,j,k))
      amax = max(amax, array(i,j,k))
      n = n + 1
    enddo ; enddo ; enddo
    amean = reproducing_sum(array(hi%isc:hi%iec,hi%jsc:hi%jec,:))
    call sum_across_pes(n)
    call min_across_pes(amin)
    call max_across_pes(amax)
    amean = amean / real(n)
    if (is_root_pe()) call chk_sum_msg("h-point:",amean*scale,amin*scale,amax*scale,mesg)
  end subroutine substats

---

The documentation for this interface was generated from the following file:

• /home/adcroft/GitHub/workspace/Gaea-stats-MOM6-examples/MOM6-examples/src/MOM6/src/framework/MOM_checksums.F90