coord_sigma.F90

Go to the documentation of this file.

!> Regrid columns for the sigma coordinate
module coord_sigma

use mom_error_handler, only : mom_error, fatal

implicit none ; private

!> Control structure containing required parameters for the sigma coordinate
type, public :: sigma_cs
  private

  !> Number of levels
  integer :: nk

  !> Minimum thickness allowed for layers
  real :: min_thickness

  !> Target coordinate resolution
  real, allocatable, dimension(:) :: coordinateresolution
end type sigma_cs

public init_coord_sigma, set_sigma_params, build_sigma_column, end_coord_sigma

contains

!> Initialise a sigma_CS with pointers to parameters
subroutine init_coord_sigma(CS, nk, coordinateResolution)
  type(sigma_cs),     pointer    :: CS !< Unassociated pointer to hold the control structure
  integer,            intent(in) :: nk
  real, dimension(:), intent(in) :: coordinateResolution

  if (associated(cs)) call mom_error(fatal, "init_coord_sigma: CS already associated!")
  allocate(cs)
  allocate(cs%coordinateResolution(nk))

  cs%nk                   = nk
  cs%coordinateResolution = coordinateresolution
end subroutine init_coord_sigma

subroutine end_coord_sigma(CS)
  type(sigma_cs), pointer :: CS

  ! nothing to do
  if (.not. associated(cs)) return
  deallocate(cs%coordinateResolution)
  deallocate(cs)
end subroutine end_coord_sigma

subroutine set_sigma_params(CS, min_thickness)
  type(sigma_cs), pointer    :: CS
  real, optional, intent(in) :: min_thickness

  if (.not. associated(cs)) call mom_error(fatal, "set_sigma_params: CS not associated")

  if (present(min_thickness)) cs%min_thickness = min_thickness
end subroutine set_sigma_params


!> Build a sigma coordinate column
subroutine build_sigma_column(CS, nz, depth, totalThickness, zInterface)
  type(sigma_cs),        intent(in)    :: CS !< Coordinate control structure
  integer,               intent(in)    :: nz !< Number of levels
  real,                  intent(in)    :: depth !< Depth of ocean bottom (positive in m)
  real,                  intent(in)    :: totalThickness !< Column thickness (positive in m)
  real, dimension(nz+1), intent(inout) :: zInterface !< Absolute positions of interfaces

  ! Local variables
  integer :: k

  zinterface(nz+1) = -depth
  do k = nz,1,-1
    zinterface(k) = zinterface(k+1) + (totalthickness * cs%coordinateResolution(k))
    ! Adjust interface position to accomodate inflating layers
    ! without disturbing the interface above
    if (zinterface(k) < (zinterface(k+1) + cs%min_thickness)) then
      zinterface(k) = zinterface(k+1) + cs%min_thickness
    endif
  enddo
end subroutine build_sigma_column

end module coord_sigma